74cd991e7e
That way, data source address does not depend on any other unrelated change in linker script. This also fixes cases when .data input section is aligned on 8 bytes. The new version does not provide any address for the output section so that it is aligned to the strictest input section. The _data_loadaddr symbol will always take this alignment into account.
98 lines
2.6 KiB
Plaintext
98 lines
2.6 KiB
Plaintext
/*
|
|
* This file is part of the libopencm3 project.
|
|
*
|
|
* Copyright (C) 2009 Uwe Hermann <uwe@hermann-uwe.de>
|
|
* Copyright (C) 2012 Michael Ossmann <mike@ossmann.com>
|
|
* Copyright (C) 2012 Benjamin Vernoux <titanmkd@gmail.com>
|
|
*
|
|
* This library is free software: you can redistribute it and/or modify
|
|
* it under the terms of the GNU Lesser General Public License as published by
|
|
* the Free Software Foundation, either version 3 of the License, or
|
|
* (at your option) any later version.
|
|
*
|
|
* This library is distributed in the hope that it will be useful,
|
|
* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
* GNU Lesser General Public License for more details.
|
|
*
|
|
* You should have received a copy of the GNU Lesser General Public License
|
|
* along with this library. If not, see <http://www.gnu.org/licenses/>.
|
|
*/
|
|
|
|
/* Generic linker script for LPC43XX targets using libopencm3. */
|
|
|
|
/* Memory regions must be defined in the ld script which includes this one. */
|
|
|
|
/* Enforce emmition of the vector table. */
|
|
EXTERN (vector_table)
|
|
|
|
/* Define the entry point of the output file. */
|
|
ENTRY(reset_handler)
|
|
|
|
/* Define sections. */
|
|
SECTIONS
|
|
{
|
|
.text : {
|
|
. = ALIGN(0x400);
|
|
_text_ram = (. - ORIGIN(rom)) + ORIGIN(ram); /* Start of Code in RAM */
|
|
|
|
*(.vectors) /* Vector table */
|
|
*(.text*) /* Program code */
|
|
. = ALIGN(4);
|
|
*(.rodata*) /* Read-only data */
|
|
. = ALIGN(4);
|
|
} >rom
|
|
|
|
/* exception index - required due to libgcc.a issuing /0 exceptions */
|
|
__exidx_start = .;
|
|
.ARM.exidx : {
|
|
*(.ARM.exidx*)
|
|
} > rom
|
|
__exidx_end = .;
|
|
|
|
. = ALIGN(4);
|
|
_etext = .;
|
|
_etext_ram = (. - ORIGIN(rom)) + ORIGIN(ram);
|
|
_etext_rom = (. - ORIGIN(rom)) + ORIGIN(rom_flash);
|
|
|
|
.data : {
|
|
_data = .;
|
|
*(.data*) /* Read-write initialized data */
|
|
. = ALIGN(4);
|
|
_edata = .;
|
|
} >ram_data AT >rom
|
|
_data_loadaddr = LOADADDR(.data);
|
|
|
|
.bss : {
|
|
*(.bss*) /* Read-write zero initialized data */
|
|
*(COMMON)
|
|
. = ALIGN(4);
|
|
_ebss = .;
|
|
} >ram_data
|
|
|
|
/* exception unwind data - required due to libgcc.a issuing /0 exceptions */
|
|
.ARM.extab : {
|
|
. = _ebss;
|
|
*(.ARM.extab*)
|
|
} >ram_data
|
|
|
|
/*
|
|
* The .eh_frame section appears to be used for C++ exception handling.
|
|
* You may need to fix this if you're using C++.
|
|
*/
|
|
/DISCARD/ : { *(.eh_frame) }
|
|
|
|
/*
|
|
* Another section used by C++ stuff, appears when using newlib with
|
|
* 64bit (long long) printf support - discard it for now.
|
|
*/
|
|
/DISCARD/ : { *(.ARM.exidx) }
|
|
|
|
. = ALIGN(4);
|
|
end = .;
|
|
|
|
/* Leave room above stack for IAP to run. */
|
|
__StackTop = ORIGIN(ram) + LENGTH(ram) - 32;
|
|
PROVIDE(_stack = __StackTop);
|
|
}
|